Build an Arduino night lamp with a button and a dimmer

An Arduino night lamp needs three parts and one idea. A button toggles the lamp, a knob sets its brightness, and an LED on a PWM pin is the lamp. The idea is a bool that remembers whether the lamp is on, flipped once per press, so the lamp stays on after you let go.

The wiring

• A push button from pin 2 to GND, with the pin set to INPUT_PULLUP: released reads HIGH, pressed reads LOW
• A 10 kΩ potentiometer with its ends on 5V and GND and its wiper on A0
• An LED on pin 9, a PWM pin, through a 220 Ω resistor to GND

The plan

1. Remember: a bool lampOn, false at power-up, so the lamp starts off whatever the knob says.
2. The press: when pin 2 reads LOW, flip lampOn, then wait out the bounce and wait for the release.
3. The brightness: while the lamp is on, read A0, map 0 to 1023 into 0 to 255, and analogWrite it to pin 9.
4. Off means off: while it's off, analogWrite 0.

Live experiment

Find the right glow

A dark bedroom with Pip as the bulb. One press of the button turns the lamp on, the next turns it off, and it stays as you left it in between. Turn the knob to set how bright it glows while it's on. While it's off, the knob does nothing.

Try it yourself: free lesson

“Project: Night lamp” is the project that ends Blink Bay, Embedded Systems World 1. Free with an account. Lessons unlock in order, so you’ll do the 6 before it first.

The sketch

bool lampOn = false;

void setup() {
  pinMode(2, INPUT_PULLUP);
  pinMode(9, OUTPUT);
}

void loop() {
  if (digitalRead(2) == LOW) {        // a press
    lampOn = !lampOn;                 // flip on or off
    delay(50);                        // let the contacts settle
    while (digitalRead(2) == LOW) {}  // wait for the release
    delay(50);                        // let the release settle
  }

  if (lampOn) {
    int level = map(analogRead(A0), 0, 1023, 0, 255);
    analogWrite(9, level);
  } else {
    analogWrite(9, 0);
  }
}

! means NOT, so lampOn = !lampOn turns false into true and back again. The while holds the program until the finger lifts, so one press flips the lamp exactly once, however long it's held.

Check the numbers

The knob is a voltage divider: three quarters of the way round, A0 sees about 3.75 V and reads about 768. map() turns that into 768 × 255 ÷ 1023 ≈ 191, rounded down, so pin 9 is on about 75% of each cycle. The brightness is read on every pass of loop(), so turning the knob changes the glow straight away.